代码之家  ›  专栏  ›  技术社区  ›  Edward

Access连续表单操作记录顺序[重复]

  •  1
  • Edward  · 技术社区  · 8 年前

    我的数据库是为滑雪比赛建立的。这个想法是,你可以填写人们滑雪的时间,数据库会根据设定时间第一的人、你的性别和年龄自动计算你获得了什么样的奖牌。我制作了一个表格,可以注册并给出所有结果。

    我现在唯一的问题是,当有人注册时,必须按年龄订购。我这么做了,但现在自动编号都搞砸了。

    我想要的是,我可以把所有参赛者的名字输入,然后我想要一个查询,我可以选择它来分配所有的起始号码。即使号码已经分配完毕,如果最近有人加入,我也要重新设置并重新分配。我不想删除自动编号字段并重新创建,因为大多数时候我自己不会使用它,但其他人会使用它,所以我想简单地按一下分配它的按钮。

    提前谢谢!

    Example how my database and a competition looks like

    0 回复  |  直到 9 年前
        1
  •  0
  •   Gustav    9 年前

    自动编号字段仅用于标识记录。不多不少。

    你需要的是一个 优先事项 (或 等级 )菲尔德。

    在显示记录的表单中,对该字段运行如下代码:

    Private Sub Priority_AfterUpdate()
    
        Dim rst             As DAO.Recordset
        Dim lngId           As Long
        Dim lngPriorityNew  As Long
        Dim lngPriorityFix  As Long
    
        ' Save record.
        Me.Dirty = False
    
        ' Prepare form.
        DoCmd.Hourglass True
        Me.Repaint
        Me.Painting = False
    
        ' Current Id and priority.
        lngId = Me!Id.Value
        lngPriorityFix = Nz(Me!Priority.Value, 0)
        If lngPriorityFix <= 0 Then
            lngPriorityFix = 1
            Me!Priority.Value = lngPriorityFix
            Me.Dirty = False
        End If
    
        ' Rebuild priority list.
        Set rst = Me.RecordsetClone
        rst.MoveFirst
        While rst.EOF = False
            If rst!Id.Value <> lngId Then
                lngPriorityNew = lngPriorityNew + 1
                If lngPriorityNew = lngPriorityFix Then
                    ' Move this record to next lower priority.
                    lngPriorityNew = lngPriorityNew + 1
                End If
                If Nz(rst!Priority.Value, 0) = lngPriorityNew Then
                    ' Priority hasn't changed for this record.
                Else
                    ' Assign new priority.
                    rst.Edit
                        rst!Priority.Value = lngPriorityNew
                    rst.Update
                End If
            End If
            rst.MoveNext
        Wend
    
        ' Reorder form and relocate record.
        Me.Requery
        Set rst = Me.RecordsetClone
        rst.FindFirst "Id = " & lngId & ""
        Me.Bookmark = rst.Bookmark
    
        ' Present form.
        Me.Painting = True
        DoCmd.Hourglass False
    
        Set rst = Nothing
    
    End Sub
    

    只要给任何记录分配一个等级,记录就会根据需要重新编号。

    推荐文章