代码之家 › 专栏 › 技术社区 › Landers

将矩阵转换为包含所有值的列表

matrix excel arrays

Landers · 技术社区 · 10 月前

我有一个矩阵,它有行名和;我试图将其转换为列表的标题名称。有没有一个公式可以做到这一点?我尝试了一些选择,但无法理解如何解释这个问题。因此,请查看图片以了解清楚。

我正试图将矩阵转换为一个列表,我可以将其脚本化到系统中。

0 回复 | 直到 10 月前

VBasic2008 10 月前

一个基本的缺点

=LET(table,A1:D5,
    h,TAKE(table,1),
    d,DROP(table,1),
    srl,TAKE(d,,1),
    scl,DROP(h,,1),
    sv,DROP(d,,1),
    drl,TOCOL(IF(SEQUENCE(,COLUMNS(scl)),srl)),
    dcl,TOCOL(IF(SEQUENCE(ROWS(srl)),scl)),
    dv,TOCOL(sv),
    r,HSTACK(drl,dcl,dv),
    r)

更换最底部 r 与任何其他变量一起查看它所包含的内容。

删除冗余变量后 h , sv ,以及 r :

=LET(table,A1:D5,
    d,DROP(table,1),
    srl,TAKE(d,,1),
    scl,DROP(TAKE(table,1),,1),
    drl,TOCOL(IF(SEQUENCE(,COLUMNS(scl)),srl)),
    dcl,TOCOL(IF(SEQUENCE(ROWS(srl)),scl)),
    dv,TOCOL(DROP(d,,1)),
    HSTACK(drl,dcl,dv))

进一步删除变量 drl , dcl ,以及 dv :

=LET(table,A1:D5,
    d,DROP(table,1),
    srl,TAKE(d,,1),
    scl,DROP(TAKE(table,1),,1),
    HSTACK(TOCOL(IF(SEQUENCE(,COLUMNS(scl)),srl)),
        TOCOL(IF(SEQUENCE(ROWS(srl)),scl)),
        TOCOL(DROP(d,,1))))

或相同:

=LET(
    table,A1:D5,
    d,DROP(table,1),
    srl,TAKE(d,,1),
    scl,DROP(TAKE(table,1),,1),
    HSTACK(
        TOCOL(IF(SEQUENCE(,COLUMNS(scl)),srl)),
        TOCOL(IF(SEQUENCE(ROWS(srl)),scl)),
        TOCOL(DROP(d,,1))
    )
)

推荐文章

Megrez7 · C#ToArray转换合并为一行,导致数组元素更改

4 月前

bairog · 从按属性筛选的对象数组字典中创建值数组

4 月前

Anka HanÄ±m · 关于结构和动态数组地址的问题

4 月前

Swapnil Supekar · 将二维阵列转换为一维阵列,并将一维阵列粘贴到另一张图纸上

5 月前

Lorenzo Bertolaccini · 在Angular项目中通过对话框后,在控制台中显示但在HTML中不显示的数据数组

5 月前

MaSc. H. · 大小与阵列大小

5 月前

Geremia · 2D NumPy数组+1D数组?

5 月前

MARTIN · 交换第一个和最后一个单词,反转所有中间的字符

6 月前

Paul Williams · 迭代数组时输出有问题

6 月前

Oliver Morgan · PostgreSQL错误:无法累积不同维度的数组

6 月前