如何在代码中检测会话是否已启用,而不仅仅是获取错误

关于使用isObject()方法的建议,结果并不好。以下asp。。。

<%@EnableSessionState=False%>
<% option explicit

response.write "session enabled=" &  IsObject(Session) 
response.end

%>

结果

Microsoft VBScript运行时错误“800a01f4”

/errortest.asp,第6行

因此,会话对象似乎被标记为真正没有声明。

我的结论是构造一个如下的函数。

<%@EnableSessionState=False%>
<% option explicit

response.write "session enabled=" &  isSessionEnabled()  ' <-- returns false 
response.end

function isSessionEnabled()
    dim s

    isSessionEnabled = true     ' Assume we will exit  as true - override in test 
    err.clear()                 ' Clear the err setting down
    on error resume next        ' Prepare to error

    s = session("foobar")       ' if session exists this will result as err.number = 0 

    if err.number <> 0 then 
        on error goto 0         ' reset the error object behaviour                  
       isSessionEnabled = false ' indicate fail - session does not exist.
       exit function            ' Leave now, our work is done
    end if
    on error goto 0             ' reset the error object behaviour
end function                    ' Returns true if get to this point

%>

If isSessionEnabled() then
    ' do something with session 
else
    ' don't be messin with session.
end if