将字符串的所有实例提取到连接的结果中

只是另一个内联选项,不限于8K

例子

Declare @YourTable table (ID int,SomeCol varchar(max))
Insert into @YourTable values
 (1,'exec quarterly_run 1, ''BW'' exec quarterly_run_2 1, ''QR '' exec quarterly_run 2, ''VAS'' exec quarterly_run 1, ''WR'' exec quarterly_run 3, ''RW'' exec quarterly_run_2 1, ''ASF'' exec quarterly_run_3 1, ''ALL''')
,(2,'declare @rundate datetime, @rptqtr datetime, @qtr int

set @rundate = getdate() set @rptqtr = ''06/30/2016''

set @qtr = (select datediff(quarter,@rptqtr,@rundate))

exec quarterly_extract @qtr
')
,(3,'exec Daily_Sync_Process exec Daily_Process')

;with cte as (
Select A.ID
      ,C.*
 From  @YourTable A
 Cross Apply (values (replace(replace(SomeCol,char(13),' '),char(10),' '))) B(CleanString)
 Cross Apply (
                Select RetSeq,RetVal = case when Lag(RetVal,1) over (Order by RetSeq) in ('Exec','Execute') then RetVal else null end
                From (
                        Select RetSeq = Row_Number() over (Order By (Select null))
                              ,RetVal = LTrim(RTrim(B.i.value('(./text())[1]', 'varchar(max)')))
                        From  (Select x = Cast('<x>' + replace((Select replace(CleanString,' ','§§Split§§') as [*] For XML Path('')),'§§Split§§','</x><x>')+'</x>' as xml).query('.')) as A 
                        Cross Apply x.nodes('x') AS B(i)
                     ) C1
             ) C
)
Select A.ID
      ,NewString = Stuff((Select ', ' +RetVal From cte Where ID=A.ID Order By RetSeq For XML Path ('')),1,2,'') 
 From cte A
 Group By A.ID

退换商品

ID  NewString
1   quarterly_run, quarterly_run_2, quarterly_run, quarterly_run, quarterly_run, quarterly_run_2, quarterly_run_3
2   quarterly_extract
3   Daily_Sync_Process, Daily_Process

所以如果你想马上得到 exec 然后我在空间上分裂,然后使用自连接。下面是使用以下函数的代码,它是 Jeff Moden's splitter.

with cte as(
select
    job_id
    ,step_name
    ,step_id
    ,s.ItemNumber
    ,s.Item
from msdb..sysjobsteps
--split on the space
cross apply dbo.DelimitedSplit8K(command,' ') s)

select 
    c.job_id
    ,c.step_id
    ,c.step_name
    ,c.Item
    ,c2.Item
from cte c
--self join to get exec myproc in the same row
full join
    cte c2 on 
    c2.ItemNumber = c.ItemNumber + 1 
    and c.job_id = c2.job_id
    and c.step_id = c2.step_id
--we only care where the base table has exec or execute (not executed, etc)
where c.Item = 'exec' or c.Item = 'execute'
order by 
    c.job_id, c.step_id, c.ItemNumber

当命令 exec someproc 有两个空间。你可以用一个 replace() 但您必须多次嵌套此替换以尽可能多地占用空间。你可以在 command 拆分器函数中的列

--here we replace two spaces with 1 for the entire command
cross apply dbo.DelimitedSplit8K(replace(command,'  ',' '),' ') s)

拆分器函数

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO


CREATE FUNCTION [dbo].[DelimitedSplit8K] (@pString VARCHAR(8000), @pDelimiter CHAR(1))
--WARNING!!! DO NOT USE MAX DATA-TYPES HERE!  IT WILL KILL PERFORMANCE!

RETURNS TABLE WITH SCHEMABINDING AS
RETURN

/* "Inline" CTE Driven "Tally Table" produces values from 1 up to 10,000... enough to cover VARCHAR(8000)*/

  WITH E1(N) AS (
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
                ),                          --10E+1 or 10 rows
       E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
       E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
 cteTally(N) AS (--==== This provides the "base" CTE and limits the number of rows right up front
                     -- for both a performance gain and prevention of accidental "overruns"
                 SELECT TOP (ISNULL(DATALENGTH(@pString),0)) ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
                ),
cteStart(N1) AS (--==== This returns N+1 (starting position of each "element" just once for each delimiter)
                 SELECT 1 UNION ALL
                 SELECT t.N+1 FROM cteTally t WHERE SUBSTRING(@pString,t.N,1) = @pDelimiter
                ),
cteLen(N1,L1) AS(--==== Return start and length (for use in substring)
                 SELECT s.N1,
                        ISNULL(NULLIF(CHARINDEX(@pDelimiter,@pString,s.N1),0)-s.N1,8000)
                   FROM cteStart s
                )
--===== Do the actual split. The ISNULL/NULLIF combo handles the length for the final element when no delimiter is found.
 SELECT ItemNumber = ROW_NUMBER() OVER(ORDER BY l.N1),
        Item       = SUBSTRING(@pString, l.N1, l.L1)
   FROM cteLen l


GO