代码之家  ›  专栏  ›  技术社区  ›  Michael

使用FILTER时,LET函数内的COUNTIF出现Excel#VALUE错误

  •  0
  • Michael  · 技术社区  · 2 年前

    我正试着用 LET , FILTER , COUNTIF 以及用于统计表列中唯一值的出现次数的动态范围。

    我有一张excel表格 tbl 有一列 df_col 这样地:

    df_col
    一
    一
    b
    c
    c
    c

    我编写了以下excel函数,该函数在表中的计数旁边输出唯一值。

    =LET(
      col_all; tbl[df_col];
      col_uniq; UNIQUE(col_all);
      col_count; COUNTIF(col_all; col_uniq);
      HSTACK(col_uniq; col_count)
    )
    

    我得到的结果是我所期望的

    一 2.
    b 1.
    c 3.

    接下来我想添加一些 过滤器 在列上为数据的子集执行此操作。

    =LET(
      col_filtered; FILTER(tbl[df_col]; tbl[df_col]<="b");
      col_uniq; UNIQUE(col_filtered);
      col_count; COUNTIF(col_filtered; col_uniq);
      HSTACK(col_uniq; col_count);
    )
    

    结果引发错误。看起来 COUNTIF 函数对检索到的列表无效。

    一 #值
    b #值
    #不适用 #值

    运行公式评估显示中存在错误 COUNTIF 部分尽管如此,在没有 LET 功能运行良好。

    有什么问题?

    2 回复  |  直到 2 年前
        1
  •  0
  •   Black cat    2 年前

    COUNTIF 函数需要一系列单元格。

    在第一个示例中,对表的引用被转换为单元格范围。

    在第二个和注释中,传递的参数是数组,函数不接受这些数组。这会导致#VALUE错误

    信息: Microsoft

        2
  •  0
  •   Michael    2 年前

    我找到了一个解决方法 COUNTIF 适用于我的案例的引用限制

    =LET(
      col_all; FILTER(tbl[df_col]; tbl[df_col]<="b");
      col_uniq; UNIQUE(col_all);
      col_count; BYROW(col_uniq; LAMBDA(x; SUM(--(col_all=x))));
      res;HSTACK(col_uniq; col_count);
      res
    )
    
    推荐文章