代码之家 › 专栏 › 技术社区 › hcknl

Kotlin中默认构造函数中的另外两种类型?

kotlin-reflect kotlin android

hcknl · 技术社区 · 7 年前

自从我用了 科特林反射 为了调用我的默认值和声明的值,我看到了第二个不同的构造函数。

我意识到两个不同的领域 int arg3 添加到我的构造函数中。

data class Model(
    @SerializedName("xyz") val entity: String?,
    @SerializedName("abc") val id: Long? = null
)
val constructors = clazz.declaredConstructors // how I call the constructors

我真正的问题是为什么我有这两个字段,以及它背后的逻辑是什么?

提前谢谢。

1 回复 | 直到 7 年前

hotkey 7 年前

这两个参数被添加到Kotlin编译器为具有默认参数的所有函数和构造函数生成的特殊合成成员中。

使用Java反射,您可以通过检查 isSynthetic() 找到一个不是。

整数参数是位掩码。当从Kotlin调用这样的函数时,将生成一个位掩码并作为参数传递。这些位显示函数的哪些默认参数是通过显式参数传递的,哪些应该使用默认值。

DefaultConstructorMarker Int 最后传递给marker参数的参数不会以任何方式使用,并且始终是 null .

事实上,为每个函数或构造函数分别生成了两个方法或构造函数,它们至少有一个默认参数:一个与声明的签名相同且没有附加参数,另一个也接受位掩码和标记。

如果您检查这样一个函数的字节码,您会发现函数声明大致如下:

fun foo(bar: String, baz: List<String> = emptyList(), qux: Set<String> = emptySet()) = 0

// access flags 0x19
// signature (Ljava/lang/String;Ljava/util/List<Ljava/lang/String;>;Ljava/util/Set<Ljava/lang/String;>;)I
// declaration: int foo(java.lang.String, java.util.List<java.lang.String>, java.util.Set<java.lang.String>)
public final static foo(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
)I
  // annotable parameter count: 3 (visible)
  // annotable parameter count: 3 (invisible)
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 0
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 1
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 2
L0
  ALOAD 0
  LDC "bar"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 1
  LDC "baz"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 2
  LDC "qux"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
L1
  LINENUMBER 16 L1
  ICONST_0
  IRETURN
L2
  LOCALVARIABLE bar Ljava/lang/String; L0 L2 0
  LOCALVARIABLE baz Ljava/util/List; L0 L2 1
  LOCALVARIABLE qux Ljava/util/Set; L0 L2 2
  MAXSTACK = 2
  MAXLOCALS = 3

生成的用于处理位掩码并在必要时计算默认值的包装器是一个单独的方法:

// access flags 0x1009
public static synthetic foo$default(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
    I
    Ljava/lang/Object;
)I
  ILOAD 3
  ICONST_2
  IAND
  IFEQ L0
L1
  LINENUMBER 16 L1
  INVOKESTATIC kotlin/collections/CollectionsKt.emptyList ()Ljava/util/List;
  ASTORE 1
L0
  ILOAD 3
  ICONST_4
  IAND
  IFEQ L2
  INVOKESTATIC kotlin/collections/SetsKt.emptySet ()Ljava/util/Set;
  ASTORE 2
L2
  ALOAD 0
  ALOAD 1
  ALOAD 2
  INVOKESTATIC FooKt.foo (Ljava/lang/String;Ljava/util/List;Ljava/util/Set;)I
  IRETURN
  MAXSTACK = 3
  MAXLOCALS = 5

请注意后者如何检查位掩码(使用 ILOAD 3 ICONST_x , IAND )然后有条件地(当 IFEQ Lx (不跳过)计算默认参数。

构造函数不同于普通函数,因为它们不能有后缀 $default 在名称中,因此标记是必要的,以避免可能的签名冲突。