代码之家 › 专栏 › 技术社区 › Umar Abdullah

如何将小计按钮添加到集成数据访问(ALV with IDA)工具栏报表?

abap

0

Umar Abdullah · 技术社区 · 7 年前

我想添加小计按钮集成数据访问(ALV与IDA)工具栏报告。与SALV的功能类似。我也附上了图片。

SALV subtotal Button

IDA Total

1 回复 | 直到 7 年前

1

mkysoft 7 年前

此按钮已存在,您需要完成以下要求:

至少一个总计列。
至少一个已排序列。

更多细节见 ZEVOLVING 博客 Column Settings 发布和 SAP Learners blog post

工作示例:

CLASS lcl_alv DEFINITION.
  PUBLIC SECTION.
    METHODS:
      generate_alv.
  PRIVATE SECTION.
    DATA: o_salv_ida TYPE REF TO if_salv_gui_table_ida.
ENDCLASS.


START-OF-SELECTION.
  NEW lcl_alv( )->generate_alv( ).

CLASS lcl_alv IMPLEMENTATION.
  METHOD generate_alv.
    o_salv_ida = cl_salv_gui_table_ida=>create( iv_table_name = 'SBOOK' ).

    DATA(lo_layout) = o_salv_ida->default_layout( ).
    DATA(lt_sort_rule) = VALUE if_salv_gui_types_ida=>yt_sort_rule(
                       ( field_name = 'FLDATE'
                         descending = abap_false
                         is_grouped = abap_true ) ).
    lo_layout->set_sort_order( it_sort_order = lt_sort_rule ).

    DATA(lt_aggr_rules) = VALUE if_salv_gui_types_ida=>yt_aggregation_rule(
                       ( field_name = 'LUGGWEIGHT'
                         function   = if_salv_service_types=>cs_function_code-sum ) ).
    lo_layout->set_aggregations( lt_aggr_rules ).

    o_salv_ida->fullscreen( )->display( ).

  ENDMETHOD.
ENDCLASS.