代码之家 › 专栏 › 技术社区 › Warren P

如何将文件从explorershell拖放到Delphi应用程序中的VirtualTreeView控件中?

virtualtreeview windows-shell drag-and-drop delphi

Warren P · 技术社区 · 14 年前

Mike Lischke在VirtualTreeView中提供了广泛的拖放支持,我正在使用TVirtualStringTree,它有一些关于拖放的事件,但我不知道如何让它接受从windows资源管理器shell将一些文件拖放到我的应用程序中的shell。我想加载文件,当它们被拖到drop控件上时。

我尝试使用andersmelander的第三方代码集来处理拖放,但是由于VirtualTreeView已经将自己注册为拖放目标,所以我不能使用它。

编辑:我找到了一个简单的解决方法:关闭toAcceptOLEDrop-inVT.TreeOptions.mischoptions选项.

2 回复 | 直到 14 年前

Linas 14 年前

我的实现(与Delphi2010配合得很好)。必须添加ActiveX、ShellApi以用于编译):

procedure TfMain.vstTreeDragDrop(Sender: TBaseVirtualTree; Source: TObject;
  DataObject: IDataObject; Formats: TFormatArray; Shift: TShiftState;
  Pt: TPoint; var Effect: Integer; Mode: TDropMode);
var
  I, j: Integer;
  MyList: TStringList;
  AttachMode: TVTNodeAttachMode;
begin
  if Mode = dmOnNode then
    AttachMode := amInsertBefore
  else if Mode = dmAbove then
    AttachMode := amInsertBefore
  else if Mode = dmBelow then
    AttachMode := amInsertAfter
  else
    AttachMode := amAddChildLast;

  MyList := TStringList.Create;
  try
    for i := 0 to High(formats) - 1 do
    begin
      if (Formats[i] = CF_HDROP) then
      begin
        GetFileListFromObj(DataObject, MyList);

        //here we have all filenames
        for j:=0 to MyList.Count - 1 do
        begin
          Sender.InsertNode(Sender.DropTargetNode, AttachMode);
        end; 
      end;  
    end;
  finally
    MyList.Free;
  end;
end;

procedure TfMain.GetFileListFromObj(const DataObj: IDataObject;
  FileList: TStringList);
var
  FmtEtc: TFormatEtc;                   // specifies required data format
  Medium: TStgMedium;                   // storage medium containing file list
  DroppedFileCount: Integer;            // number of dropped files
  I: Integer;                           // loops thru dropped files
  FileNameLength: Integer;              // length of a dropped file name
  FileName: string;                 // name of a dropped file
begin
  // Get required storage medium from data object
  FmtEtc.cfFormat := CF_HDROP;
  FmtEtc.ptd := nil;
  FmtEtc.dwAspect := DVASPECT_CONTENT;
  FmtEtc.lindex := -1;
  FmtEtc.tymed := TYMED_HGLOBAL;
  OleCheck(DataObj.GetData(FmtEtc, Medium));
  try
    try
      // Get count of files dropped
      DroppedFileCount := DragQueryFile(
        Medium.hGlobal, $FFFFFFFF, nil, 0
        );
      // Get name of each file dropped and process it
      for I := 0 to Pred(DroppedFileCount) do
        begin
          // get length of file name, then name itself
          FileNameLength := DragQueryFile(Medium.hGlobal, I, nil, 0);
          SetLength(FileName, FileNameLength);
          DragQueryFileW(
            Medium.hGlobal, I, PWideChar(FileName), FileNameLength + 1
            );
          // add file name to list
          FileList.Append(FileName);
        end;
    finally
      // Tidy up - release the drop handle
      // don't use DropH again after this
      DragFinish(Medium.hGlobal);
    end;
  finally
    ReleaseStgMedium(Medium);
  end;

end;

Germán Estévez -Neftalí- 14 年前

我使用此方法捕获(接收)从资源管理器拖到控件中的文件。
你可以在你的控件上测试它。在标准TTreeView中工作正常。

将ShellAPI添加到uses。

  private
    originalEditWindowProc : TWndMethod;
    procedure EditWindowProc(var Msg:TMessage);
    // accept the files dropped
    procedure FilesDrop(var Msg: TWMDROPFILES);

创建表单时:

  // Assign procedures
  originalEditWindowProc := TreeView1.WindowProc;
  TreeView1.WindowProc := EditWindowProc;
  // Aceptar ficheros arrastrados  // Accept the files
  ShellAPI.DragAcceptFiles(TreeView1.Handle, True);

// Al arrastrar ficheros sobre el TV.  On drop files to TV
procedure TForm1.FilesDrop(var Msg: TWMDROPFILES);
var
  i:Integer;
  DroppedFilename:string;
  numFiles : longInt;
  buffer : array[0..MAX_PATH] of char;
begin
  // NÃºmero de ficheros arrastrados // Number of files
  numFiles := DragQueryFile(Msg.Drop, $FFFFFFFF, nil, 0) ;

  // Recorrido por todos los arrastrados // Accept all files
  for i := 0 to (numFiles - 1) do begin

    DragQueryFile(Msg.Drop, i, @buffer, sizeof(buffer));

    // Proteccion
    try
      DroppedFilename := buffer;

      // HERE you can do something with the file...
      TreeView1.Items.AddChild(nil, DroppedFilename);
    except
      on E:Exception do begin
        // catch
      end;
    end;
  end;
end;


procedure TForm1.EditWindowProc(var Msg: TMessage);
begin
  // if correct message, execute the procedure
  if Msg.Msg = WM_DROPFILES then begin
    FilesDrop(TWMDROPFILES(Msg))
  end
  else begin
    // in other case do default...
    originalEditWindowProc(Msg) ;
  end;
end;

我希望这对你有用。

当做。