在Haskell命令行应用程序中提示输入密码

执行以下操作:

module Main
where

import System.IO
import Control.Exception

main :: IO ()
main = getPassword >>= putStrLn . ("Entered: " ++)

getPassword :: IO String
getPassword = do
  putStr "Password: "
  hFlush stdout
  pass <- withEcho False getLine
  putChar '\n'
  return pass

withEcho :: Bool -> IO a -> IO a
withEcho echo action = do
  old <- hGetEcho stdin
  bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action

有一个 getPassword 在里面 System.Console.Haskeline . 也许这对你的案子有点过分,但也许有人会觉得有用。

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p}
pass:***
asd

可以使用 the System.Posix.Terminal module . 但是,这需要POSIX支持,因此可能无法在Windows上工作(我没有检查)。

import System.Posix.Terminal 
import System.Posix.IO (stdInput)

getPassword :: IO String
getPassword = do
    tc <- getTerminalAttributes stdInput
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately
    password <- getLine
    setTerminalAttributes stdInput tc Immediately
    return password

main = do
    putStrLn "Password:"
    password <- getPassword
    putStrLn "Name:"
    name <- getLine
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name

注意stdin是行缓冲的,所以如果使用 putStr "Password:" putStrLn ,需要先刷新缓冲区,否则提示也会被禁止。

withEcho可以用更小的噪音来写:

withEcho :: Bool -> IO a -> IO a
withEcho echo action =
    bracket (hGetEcho stdin)
            (hSetEcho stdin)
            (const $ hSetEcho stdin echo >> action)

如上所述,我建议您使用 haskeline LambdaCalculator 没有抱怨。