Applescript:在不带扩展名的文件夹中获取文件名

这是一个完整的脚本,可以满足你的要求。我不愿意把它贴出来,因为我觉得有一个简单的一行,有人会提供一个解决方案。希望这个解决方案不是 Rube Goldberg 做事的方式。

查找词典确实有 名称扩展名 属性,以便您可以执行以下操作:

tell application "Finder"
   set myFiles to name extension of file 1 of (path to desktop)
end tell

所以上面的代码只会得到用户桌面上第一个文件的扩展名。似乎有一个简单的函数来获取(基名-扩展名),但我没有找到。

下面的脚本只获取整个目录中每个文件的不带扩展名的文件名:

set filesFound to {}
set filesFound2 to {}
set nextItem to 1

tell application "Finder"
  set myFiles to name of every file of (path to desktop) --change path to whatever path you want   
end tell

--loop used for populating list filesFound with all filenames found (name + extension)
repeat with i in myFiles
  set end of filesFound to (item nextItem of myFiles)
  set nextItem to (nextItem + 1)
end repeat

set nextItem to 1 --reset counter to 1

--loop used for pulling each filename from list filesFound and then strip the extension   
--from filename and populate a new list called filesFound2
repeat with i in filesFound
  set myFile2 to item nextItem of filesFound
  set myFile3 to text 1 thru ((offset of "." in myFile2) - 1) of myFile2
  set end of filesFound2 to myFile3
  set nextItem to (nextItem + 1)
end repeat

return filesFound2

尽管上面的脚本是有效的,如果有人知道一个简单的方法来做什么,请张贴它,因为我仍然有感觉,应该有一个更简单的方法来做。也许还有一个脚本添加,这也有助于这一点。有人知道吗?

从 http://www.macosxautomation.com/applescript/sbrt/index.html :

on remove_extension(this_name)
  if this_name contains "." then
    set this_name to ¬
    (the reverse of every character of this_name) as string
    set x to the offset of "." in this_name
    set this_name to (text (x + 1) thru -1 of this_name)
    set this_name to (the reverse of every character of this_name) as string
  end if
  return this_name
end remove_extension

下面是一个applescriptish方法,可以让Finder知道剥离的文件名是什么:

set extension hidden of thisFile to true
set thisName to displayed name of thisFile
-- display dialog "hey"
set extension hidden of thisFile to false

单线方式,无查找程序,无系统事件。所以效率更高,速度更快。副作用(可能是好的,也可能是坏的):以“.”结尾的文件名将删除此字符。如果名称是多个句点,则使用“每个字符的倒序”可以使其工作。

set aName to text 1 thru ((aName's length) - (offset of "." in ¬
    (the reverse of every character of aName) as text)) of aName

作为处理程序处理名称列表的解决方案:

on RemoveNameExt(aList)
    set CleanedList to {}
    repeat with aName in aList
        set the end of CleanedList to text 1 thru ((aName's length) - (offset of ¬
            "." in (the reverse of every character of aName) as text)) of aName
    end repeat
    return CleanedList
end RemoveNameExt

当你使用“每个文件”时,我不知道如何删除扩展名 语法,但如果您不介意在每个文件中循环(示例中未显示循环),则可以:

tell application "Finder"
  set myFile to name of file 1 of somePath
  set myFile2 to text 1 thru ((offset of "." in myFile) - 1) of myFile
end tell

基于劳里·兰塔的 nice solution ,它适用于Finder不知道的扩展:

set delims to AppleScript's text item delimiters
set AppleScript's text item delimiters to "."
set myNames to {}
tell application "Finder"
    set myFiles to name of every file of (path to Desktop)
    repeat with myfile in myFiles
        set myname to name of file myfile
        if myname contains "." then set myname to (text items 1 thru -2 of myname) as text
        set end of myNames to myname
    end repeat
end tell
set AppleScript's text item delimiters to delims
return myNames

在tell“Finder”块中,它收集myNames中去掉扩展名的文件名:

repeat with f in myFiles
    set myNames's end to ¬
        (f's name as text)'s text 1 thru -(((f's name extension as text)'s length) + 2)
end repeat