1。你的图表

为了便于进一步的回答和解决方案,我注意到我的图表创建声明:

CREATE
  (a:NodeA {name: 'A'})-[:RelationType1]->(b:NodeB {name: 'B'}),
  (a)-[:RelationType2]->(b),
  (a)-[:RelationType1]->(c:NodeC {name: 'C'}),
  (b)-[:RelationType1]->(c),
  (b)-[:RelationType2]->(c);

2。渲染次数

2.1解决方案

MATCH
  (startNode)-[:RelationType1]-(endNode)-[:RelationType2]-(startNode)
  WHERE
  id(startNode) < id(endNode)
RETURN
  startNode.name AS startNodeName, endNode.name AS endNodeName;

这个 id 中的比较 WHERE 第4行的子句避免了每对有两个关系(每个方向一个),并防止从节点到它们自己创建关系。

2.2结果

╒═══════════════╤═════════════╕
│"startNodeName"│"endNodeName"│
╞═══════════════╪═════════════╡
│"A"            │"B"          │
├───────────────┼─────────────┤
│"B"            │"C"          │
└───────────────┴─────────────┘

三。计数发生次数

3.1解决方案

MATCH
  (startNode)-[:RelationType1]-(endNode)-[:RelationType2]-(startNode)
  WHERE
  id(startNode) < id(endNode)
RETURN
  count(startNode) AS amount;

3.2结果

╒════════╕
│"amount"│
╞════════╡
│2       │
└────────┘

我假设您的意思是“两个节点之间正好有两个关系的次数”,但是这里的想法是保持密码简单,这样您匹配的模式就是即插即用的。您可以使用大小来计算节点之间特定模式的出现次数,并使用exists来测试它是否简单存在。在这里,我们使用where来查找符合我们感兴趣的模式的节点对,然后返回行数作为该模式出现次数的计数。

MATCH (a), (b)
WHERE ID(a) > ID(b) // create distinction between a and b
AND SIZE((a)--(b)) = 2 // match the pattern we are looking for between them
RETURN COUNT(*) as occurrences // return count

模式也可以是 EXISTS((a)-[:r1]-(b)-[:r2]-(a)) (注意 WHERE EXISTS((a)--(b)) 等于 WHERE (a)--(b) 但第一种形式更清楚一点)