用perl-regex解析XML文件

Never ever use Regex to handle markup languages.

此答案的原始版本(见下文)已使用 XML::XPath . 格兰特·麦克莱恩在评论中说:

XML::XPath 是一个旧的未维护的模块。 XML::LibXML

所以我做了一个新版本 XML::LibXML (谢谢,格兰特):

use warnings;
use strict;
use XML::LibXML;

my $doc   = XML::LibXML->load_xml(location => 'articles.xml');
my $xp    = XML::LibXML::XPathContext->new($doc->documentElement);
my $xpath = '/articles/article[position() < 4]';

foreach my $article ( $xp->findnodes($xpath) ) {
  # now do something with $article
  print $article.": ".$article->getName."\n";
}

对我来说这个指纹:

XML::LibXML::Element=SCALAR(0x346ef90): article
XML::LibXML::Element=SCALAR(0x346ef30): article
XML::LibXML::Element=SCALAR(0x346efa8): article

• $doc 将 XML::LibXML::Document
• 类型 $xp XML::LibXML::XPathContext .
• 的返回类型 $xp->findnodes() XML::LibXML::NodeList .
• 类型 $article 是 XML::LibXML::Element

原版答案,基于 包裹:

use warnings;
use strict;
use XML::XPath;

my $xp    = XML::XPath->new(filename => 'articles.xml');
my $xpath = '/articles/article[position() < 4]';

foreach my $article ( $xp->findnodes($xpath)->get_nodelist ) {
  # now do something with $article
  print $article.": ".$article->getName ."\n";
}

XML::XPath::Node::Element=REF(0x38067b8): article
XML::XPath::Node::Element=REF(0x38097e8): article
XML::XPath::Node::Element=REF(0x3809ae8): article

• 类型 xp美元 是 XML::XPath
• $xp->findnodes() 是 XML::XPath::NodeSet .
• $文章 将 XML::XPath::Node::Element

在这里:

 open my $input, "<", "file.xml" or die $!;
 open my $output, ">", "truncated-file.xml" or die $!;
 my $n_articles = 0;
 while (<$input>) {
      print $output $_;
      if (m:</article>:) {
           $n_articles++;
           if ($n_articles >= 3) {
                last;
           }
      }
 }         
 close $input or die $!;
 close $output or die $!;