当垂直重传位清除时,VGA卡是否在像素缓冲区中读取?

我正在开发一款使用视频模式13H的DOS游戏。

我一直有屏幕撕裂的问题,但直到今天我都忽略了这个问题。我认为这将是一个修复的挑战,因为它将涉及延迟像素写入一段精确的时间。但这实际上是一个非常简单的修复方法。

您所要做的就是等待VGA状态字节的垂直重传位(第3位),该位在颜色模式下的端口0x3da处可用。

所以我只需要修改这个旧过程,它将我的帧缓冲区写入vga像素缓冲区,从a00:0000开始:

WRITE_FRAME PROC

;WRITES ALL 64,000 PIXELS (32,000 WORDS) IN THE FRAME BUFFER TO VIDEO MEMORY

    push es
    push di
    push ds
    push si
    push cx

    mov cx, frame
    mov ds, cx
    xor si, si             ;ds:si -> frame buffer (source)                  

    mov cx, vidMemSeg
    mov es, cx
    xor di, di             ;es:di -> video memory (destination)

    mov cx, (scrArea)/2    ;writing 32,000 words of pixels
    rep movsw              ;write the frame


    pop cx
    pop si
    pop ds
    pop di
    pop es
    ret

WRITE_FRAME ENDP

下面是修改后的过程,它等待新设置的垂直回程位:

WRITE_FRAME PROC

;WRITES ALL 64,000 PIXELS (32,000 WORDS) IN THE FRAME BUFFER TO VIDEO MEMORY

    push es
    push di
    push ds
    push si
    push ax
    push cx
    push dx

    mov cx, frame
    mov ds, cx
    xor si, si             ;ds:si -> frame buffer (source)                  

    mov cx, vidMemSeg
    mov es, cx
    xor di, di             ;es:di -> video memory (destination)

    mov cx, (scrArea)/2    ;writing 32,000 words of pixels

                           ;If vert. retrace bit is set, wait for it to clear
    mov dx, 3dah           ;dx <- VGA status register
VRET_SET:
    in al, dx              ;al <- status byte
    and al, 8              ;is bit 3 (vertical retrace bit) set
    jnz VRET_SET           ;If so, wait for it to clear

VRET_CLR:                  ;When it's cleared, wait for it to be set
    in al, dx
    and al, 8
    jz VRET_CLR            ;loop back till vert. retrace bit is newly set

    rep movsw              ;write the frame


    pop dx
    pop cx
    pop ax
    pop si
    pop ds
    pop di
    pop es
    ret

WRITE_FRAME ENDP 

它并不完全完美。还有一点不安,尤其是当精灵后面的背景向上或向下滚动时,但再看也不疼了。

我的问题是,为什么这样做有效?

我的猜测是,当设置垂直回程位时,像素已经被读取到VGA卡的内存中,并且它目前正在写入它已经加载的像素。但是,当垂直重传位被清除时,它正在将像素从a000:0000加载到本地内存中。它使用DMA,对吗?

因此,只有当VGA卡正在写入像素(位集)而不在(位清除)中加载像素时,才能安全地写入A000:0000。

或者我完全错了?