代码之家 › 专栏 › 技术社区 › justintime

如何在目录中生成Perl模块或脚本的HTML摘要?

pod perl

justintime · 技术社区 · 16 年前

是否有工具可以在目录树中生成Perl模块或脚本的HTML摘要列表?

鉴于

 =head1 NAME

 wibble.pl - does wibble actions

我想看一些像

<a href="docsforwibble">wibble.pl</a> - does wibble actions
<a href="docsforwobble">wobble.pl</a> - does wobble actions

2 回复 | 直到 16 年前

Sinan Ünür 16 年前

很容易用 Pod::Find 从 Pod::Parser 分配。

下面的脚本为在My site/lib/CGI . 这是一个示范。你最好还是 pod2html ,但此脚本可能仍然有用。

#!/usr/bin/perl

use strict; use warnings;
use autodie;

use File::Spec::Functions qw( canonpath );
use HTML::Template;
use Pod::Find qw(pod_find simplify_name);
use Pod::Select;

my $mod_top = canonpath 'c:/opt/perl/site/lib/CGI';
my $html_top = 'c:/opt/perl/html/site/lib/CGI';

my %pods = pod_find($mod_top);
my @pods;

for my $pod ( sort keys %pods ) {
    (my $link = $pod) =~ s/^\Q$mod_top//;
    $link =~ s/\.\w+\z//;
    $link = "file:///${html_top}${link}.html";

    my $name;
    {
        local *STDOUT;
        open STDOUT, '>', \$name;
        podselect({-sections => [ 'NAME' ] }, $pod);
    }
    $name = '' unless defined $name;
    $name =~ s/^=head1\s+NAME\s+//;
    $name =~ s/\s+\z//;

    push @pods, {
        POD => $pods{$pod},
        NAME => $name,
        LINK => $link,
    };
}

my $tmpl = HTML::Template->new(scalarref => \ <<EO_TMPL
<!DOCTYPE HTML>
<html>
<head><title>Index of Perl Modules</title></head>
<body>
<h1><TMPL_VAR CATEGORY></h1>
<dl>
<TMPL_LOOP PODS>
<dt><a href="<TMPL_VAR LINK>"><TMPL_VAR POD></a></dt>
<dd><TMPL_VAR NAME></dd>
</TMPL_LOOP>
</ul>
</body>
</html>
EO_TMPL
);

$tmpl->param(
    CATEGORY => 'CGI',
    PODS => \@pods,
);
$tmpl->output(print_to => \*STDOUT);

Sinan Ünür 16 年前

pod2html --recurse --podpath <dirname>

见 perldoc pod2html

推荐文章

James Finnegan · DateTime对象只能与另一个DateTime对象进行比较

1 年前

con · Negative Lookaward在perl正则表达式中不起作用

1 年前

Carsten · 使用最近的搜索模式更改文本块

1 年前

Mario Palumbo · 是否有bash-perl快捷方式来计算每行中的匹配数?

1 年前

Rawley Fowler · 我可以在Perl中为警告生成堆栈跟踪吗?

1 年前

A.Ellett · 测试-t STDIN与-t<STDIN>

2 年前

nick · 向后交换文件名

2 年前

Sangyong Gwak · 如何更改Perl Kelp应用程序的app_url

2 年前

con · 如何跳转到foreach迭代的特定点?

2 年前

A.G.Progm.Enthusiast · 如何使用Perl中的拼接从数组中一次性删除随机元素?

2 年前