代码之家 › 专栏 › 技术社区 › Drew Gibson

Delphi中GetLastError和FormatMessage的正确用法是什么?

error-handling winapi delphi

Drew Gibson · 技术社区 · 16 年前

2 回复 | 直到 16 年前

Grim 8 年前

Delphi中有一个集成的辅助函数: SysErrorMessage FormatMessage ,但在您的情况下使用起来要简单得多。只需提供您需要文本描述的错误代码。

ShowMessage(SysErrorMessage(GetLastError))

如果你想用这条消息引发异常,那就更简单了:

RaiseLastOSError;

重要 :请确保在失败的函数和的调用之间没有额外的API调用 GetLastError ,否则将重置最后一个错误。

dummzeuch Stijn Sanders 5 年前

虽然DR是正确的,但这种方法存在一个问题:它不允许您指定错误发生的上下文。见过“API函数失败”的错误吗?不知道是哪个函数,发生在哪里?

procedure RaiseLastOsErrorEx(const _Format: string);
begin
  RaiseLastOsErrorEx(GetLastError, _Format);
end;

procedure RaiseLastOsErrorEx(_ErrorCode: integer; _Format: string); overload;
var
  Error: EOSError;
begin
  if _ErrorCode <> ERROR_SUCCESS then
    Error := EOSError.CreateFmt(_Format, [_ErrorCode, SysErrorMessage(_ErrorCode)])
  else
    Error := EOsError.CreateFmt(_Format, [_ErrorCode, _('unknown OS error')]);
  Error.ErrorCode := _ErrorCode;
  raise Error;
end;

function GetLastOsError(out _Error: string; const _Format: string = ''): DWORD;
begin
  Result := GetLastOsError(GetLastError, _Error, _Format);
end;

function GetLastOsError(_ErrCode: integer; out _Error: string; const _Format: string = ''): DWORD;
var
  s: string;
begin
  Result := _ErrCode;
  if Result <> ERROR_SUCCESS then
    s := SysErrorMessage(Result)
  else
    s := _('unknown OS error');
  if _Format <> '' then
    try
      _Error := Format(_Format, [Result, s])
    except
      _Error := s;
    end else
    _Error := s;
end;

function Win32CheckEx(_RetVal: BOOL; out _ErrorCode: DWORD; out _Error: string;
  const _Format: string = ''): BOOL;
begin
  Result := _RetVal;
  if not Result then
    _ErrorCode := GetLastOsError(_Error, _Format);
end;

https://osdn.net/projects/dzlib-tools/svn/view/dzlib/trunk/src/u_dzMiscUtils.pas?view=markup&root=dzlib-tools#l313