代码之家  ›  专栏  ›  技术社区  ›  gene b.

PLS-00382:在循环中调用的存储过程上打开REF CURSOR时“表达式类型错误”

  •  0
  • gene b.  · 技术社区  · 2 年前

    我有一个外部存储过程,它在循环中调用内部存储过程。内部存储过程返回 REF CURSOR 由2部分组成,(1) V_SUCCESSFUL_COUNT 2. V_RESPONSE_CODE .

    我的外部存储过程从所有内部存储过程调用中收集这些对到相应的数组中, V_SUCCESSFUL_COUNTS 和 V_RESPONSE_CODES 。首先,它打开内部存储过程的游标,将这两个部分提取到变量中,然后将这些变量添加到数组中。

    PROCEDURE OUTER_SP(PARAM1, .., P_REF_CURSOR REF CURSOR)
    AS
        ..
        V_SUCCESSFUL_COUNT      NUMBER;
        V_RESPONSE_CODE         VARCHAR2(10);
        V_SUCCESSFUL_COUNTS     REF_TYPE_NUM_TABLE := REF_TYPE_NUM_TABLE(); /* Cumulative Successful Counts */
        V_RESPONSE_CODES        REF_VARCHAR2_ARRAY_TABLE := REF_VARCHAR2_ARRAY_TABLE(); /* Cumulative Response Codes */
        V_REF_CURSOR            SYS_REFCURSOR; /* Result from each inner SP */
    
        FOR i IN 1 .. P_REF_ID_LIST.COUNT LOOP
                        SP_INNER(PARAM1,
                                 PARAM2,
                                 ...
                                 V_REF_CURSOR);
    
            /* Add V_SUCCESSFUL_COUNT, V_RESPONSE_CODE outputs from this call to collections */
            OPEN V_REF_CURSOR /* Error here! */;
            FETCH V_REF_CURSOR INTO V_SUCCESSFUL_COUNT, V_RESPONSE_CODE;
            V_SUCCESSFUL_COUNTS.EXTEND;
            V_SUCCESSFUL_COUNTS(V_SUCCESSFUL_COUNTS.COUNT) := V_SUCCESSFUL_COUNT;
            V_RESPONSE_CODES.EXTEND;
            V_RESPONSE_CODES(V_RESPONSE_CODES.COUNT) := V_RESPONSE_CODE;
            CLOSE V_REF_CURSOR /* Error here! */;
        END LOOP;
    

    我收到了这个错误

    OPEN V_REF_CURSOR / CLOSE V_REF_CURSOR
    

    当我试图从每个内部存储过程调用中检索结果时:

    PLS-00382:表达式类型错误

    它不喜欢我在调用之前打开内部存储过程的游标 FETCH V_REF_CURSOR .

    如果我删除这些 OPEN V_REF_CURSOR / CLOSE V_REF_CURSOR 行,然后直接到 获取V_REF_CURSOR ,没有语法错误,存储过程已编译,但添加到数组中的结果不正确( NULL ),当我运行这个外部存储过程时可以看到。

    2 回复  |  直到 2 年前
        1
  •  1
  •   MT0    2 年前

    如果您正在使用 SYS_REFCURSOR 您可能使用过的数据类型 OPEN v_ref_cursor FOR ... 在里面 SP_INNER ,在这种情况下,尝试 OPEN 再次移动光标,因为它已经打开。

    删除 OPEN v_refcursor; 语句(但不是 CLOSE 语句),并且代码似乎起作用:

    CREATE PACKAGE package_name AS
      TYPE REF_TYPE_NUM_TABLE IS TABLE OF NUMBER;
      TYPE REF_VARCHAR2_ARRAY_TABLE IS TABLE OF VARCHAR2(1);
    
      PROCEDURE SP_INNER(
        PARAM1 NUMBER,
        PARAM2 NUMBER,
        V_REF_CURSOR OUT SYS_REFCURSOR
      );
    
      PROCEDURE OUTER_SP(
        PARAM1 NUMBER,
        PARAM2 NUMBER,
        P_REF_ID_LIST SYS.ODCINUMBERLIST
      );
    END;
    /
    
    CREATE PACKAGE BODY package_name AS
      PROCEDURE SP_INNER(
        PARAM1 NUMBER,
        PARAM2 NUMBER,
        V_REF_CURSOR OUT SYS_REFCURSOR
      )
      IS
      BEGIN
        OPEN v_ref_cursor FOR
          SELECT 1, 'A' FROM DUAL;
      END;
    
      PROCEDURE OUTER_SP(
        PARAM1 NUMBER,
        PARAM2 NUMBER,
        P_REF_ID_LIST SYS.ODCINUMBERLIST
      )
      AS
        V_SUCCESSFUL_COUNT      NUMBER;
        V_RESPONSE_CODE         VARCHAR2(10);
        V_SUCCESSFUL_COUNTS     REF_TYPE_NUM_TABLE := REF_TYPE_NUM_TABLE(); /* Cumulative Successful Counts */
        V_RESPONSE_CODES        REF_VARCHAR2_ARRAY_TABLE := REF_VARCHAR2_ARRAY_TABLE(); /* Cumulative Response Codes */
        V_REF_CURSOR            SYS_REFCURSOR; /* Result from each inner SP */
      BEGIN
        FOR i IN 1 .. P_REF_ID_LIST.COUNT LOOP
           SP_INNER(PARAM1, PARAM2, V_REF_CURSOR);
           /* Add V_SUCCESSFUL_COUNT, V_RESPONSE_CODE outputs from this call to collections */
           FETCH V_REF_CURSOR INTO V_SUCCESSFUL_COUNT, V_RESPONSE_CODE;
           V_SUCCESSFUL_COUNTS.EXTEND;
           V_SUCCESSFUL_COUNTS(V_SUCCESSFUL_COUNTS.COUNT) := V_SUCCESSFUL_COUNT;
           V_RESPONSE_CODES.EXTEND;
           V_RESPONSE_CODES(V_RESPONSE_CODES.COUNT) := V_RESPONSE_CODE;
           CLOSE V_REF_CURSOR /* Error here! */;
        END LOOP;
    
        FOR i IN 1 .. V_SUCCESSFUL_COUNTS.COUNT LOOP
          DBMS_OUTPUT.PUT_LINE(V_SUCCESSFUL_COUNTS(i) || ' - ' || V_RESPONSE_CODES(i));
        END LOOP;
      END;
    END;
    /
    

    然后

    BEGIN
      DBMS_OUTPUT.ENABLE();
      package_name.OUTER_SP(3.141, 42, SYS.ODCINUMBERLIST(1,2,3));
    END;
    /
    

    输出:

    1 - A
    1 - A
    1 - A
    

    fiddle

        2
  •  0
  •   Littlefoot    2 年前

    我怀疑是的 SP_INNER 那不会有任何回报。

    这里有一个演示,展示了如何做到这一点(如果一切顺利)。

    这是一个返回一些数据的查询;它用于 SP_INNER :

    SQL> select ename, sal from emp where deptno = 10;
    
    ENAME             SAL
    ---------- ----------
    CLARK            2450
    KING             5000
    MILLER           1300
    

    我的 SP_INNER 程序真的很简单;这里唯一“重要”的是,用于ref游标的查询确实返回了一些内容:

    SQL> create or replace procedure sp_inner(par_rc out sys_refcursor)
      2  is
      3  begin
      4    open par_rc for
      5      select ename, sal from emp where deptno = 10;
      6  end;
      7  /
    
    Procedure created.
    
    SQL> set serveroutput on;
    

    模拟您的匿名PL/SQL块 OUTER_SP :

    SQL> declare
      2    l_rc    sys_refcursor;
      3    l_ename emp.ename%type;
      4    l_sal   emp.sal%type;
      5  begin
      6    sp_inner(l_rc);
      7    loop
      8      fetch l_rc into l_ename, l_sal;
      9      exit when l_rc%notfound;
     10      dbms_output.put_line(l_ename||' - '||l_sal);
     11    end loop;
     12  end;
     13  /
    CLARK - 2450
    KING - 5000
    MILLER - 1300
    
    PL/SQL procedure successfully completed.
    
    SQL>
    

    正如您所看到的,输出反映了 select 语句本身返回,所以-它 作品 .

    由于你什么都没得到,检查一下 SP_INNER 正在做。

    除此之外, for 循环使用 P_REF_ID_LIST.COUNT 但你从来没说过什么 p_ref_id_list 是/包含。如果什么都没有,那个循环根本不会执行,所以这可能是另一个罪魁祸首。显示 P_REF_ID_LIST。计数 值,然后在循环中使用它来验证其值。