Delphi线程,它等待数据,处理数据,然后继续等待

OmnithreadLibrary绝对可以帮助您。来自OTL发行版的测试5应该可以帮助您开始。

在这个演示中,“开始”按钮创建线程并设置一些参数和计时器(如果不需要,可以在代码中删除)。change message“向线程发送消息,此消息在线程的omchangemessage方法中处理。然后,线程将一些信息发送回客户机(本演示中的omsendmessage,但您可以在将要在其中执行工作的同一条消息中执行此操作),并且主线程通过omniventmonitor组件接收此消息。”“停止”按钮停止工作线程。

如果在线程忙时收到更多的消息,那么在您的辅助方法完成工作后,这些消息将被排队处理。当没有什么可做时,线程将使用进程中的零CPU周期等待下一条消息。

编辑

在Delphi 2009及更高版本中, Background Worker 模式提供了一个更简单的解决方案。

waitForSingleObject()可以等待几种类型的同步对象。您可以使用Windows“事件”同步对象(与Delphi事件无关)。创建事件(在syncobjs、iirc中有一个delphi-tevent包装器),然后调用waitforsingleobject来等待该事件变为信号。当必须唤醒线程时,调用setEvent将事件置于信号状态,并返回waitForSingleObject。您可以使用waitformultipleobjects()让线程等待多个对象中的一个(或全部),它还将告诉您哪个对象已发出信号。

即使没有窗口句柄,也可以向线程发送消息。只是使用 PostThreadMessage() 而不是 SendMessage() 或 PostMessage() .如果您搜索 PostThreadMessage()。 在[Delphi]标签中-我不认为复制这里的所有内容是个好主意。

但是,如果您不了解线程编程,那么从OTL开始而不是从低级的东西开始可能确实是一件好事。

下面是一个简单的例子,你如何做到…

const
  WM_MY_RESULT = WM_USER + $1;

type
  TMyThread = class(TThread)
  private
    FKilled: Boolean;
    FListLock: TRTLCriticalSection;
    FList: TList;
    FJobAdded: TEvent;
  protected
    procedure Execute; override;
    procedure DoJob(AJob: Integer);
  public
    constructor Create(CreateSuspended: Boolean);
    destructor Destroy; override;
    procedure Kill;
    procedure PushJob(AJob: Integer);
    function  JobCount: Integer;
    function  GetJob: Integer;
  end;


  TThreadingForm = class(TForm)
    lstResults: TListBox;
    se: TSpinEdit;
    btn: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure btnClick(Sender: TObject);
  private
    FThread: TMyThread;
    procedure OnMyResultMessage(var Msg: TMessage); message WM_MY_RESULT;
  public
    { Public declarations }
  end;

var
  ThreadingForm: TThreadingForm;

implementation

{$R *.dfm}

{ TMyThread }

constructor TMyThread.Create(CreateSuspended: Boolean);
begin
  FKilled := False;
  InitializeCriticalSection(FListLock);
  FList := TList.Create;
  FJobAdded := TEvent.Create(nil, True, False, 'job.added');
  inherited;
end;

destructor TMyThread.Destroy;
begin
  FList.Free;
  FJobAdded.Free;
  DeleteCriticalSection(FListLock);
  inherited;
end;

procedure TMyThread.DoJob(AJob: Integer);
var
  res: Integer;
begin
  res := AJob * AJob * AJob * AJob * AJob * AJob;
  Sleep(1000); // so it would take some time
  PostMessage(ThreadingForm.Handle, WM_MY_RESULT, res, 0);
end;

procedure TMyThread.Execute;
begin
  inherited;
  while not FKilled or not Self.Terminated do
  begin
    EnterCriticalSection(FListLock);
    if JobCount > 0 then
    begin
      LeaveCriticalSection(FListLock);
      DoJob(GetJob)
    end
    else
    begin
      FJobAdded.ResetEvent;
      LeaveCriticalSection(FListLock);
      FJobAdded.WaitFor(10000);
    end;
  end;
end;

function TMyThread.GetJob: Integer;
begin
  EnterCriticalSection(FListLock);
  try
    Result := Integer(FList[0]);
    FList.Delete(0);
  finally
    LeaveCriticalSection(FListLock);
  end;
end;

function TMyThread.JobCount: Integer;
begin
  EnterCriticalSection(FListLock);
  Result := FList.Count;
  LeaveCriticalSection(FListLock);
end;

procedure TMyThread.Kill;
begin
  FKilled := True;
  FJobAdded.SetEvent;
  Terminate;
end;

procedure TMyThread.PushJob(AJob: Integer);
begin
  EnterCriticalSection(FListLock);
  try
    FList.Add(Pointer(AJob));
    FJobAdded.SetEvent;
  finally
    LeaveCriticalSection(FListLock);
  end;
end;

{ TThreadingForm }

procedure TThreadingForm.OnMyResultMessage(var Msg: TMessage);
begin
  lstResults.Items.Add(IntToStr(Msg.WParam));
end;

procedure TThreadingForm.FormCreate(Sender: TObject);
begin
  FThread := TMyThread.Create(False);
end;

procedure TThreadingForm.FormDestroy(Sender: TObject);
begin
  FThread.Kill;
  FThread.WaitFor;
  FThread.Free;
end;

procedure TThreadingForm.btnClick(Sender: TObject);
begin
  FThread.PushJob(se.Value);
end;